method apiExportFactoryDefaults

Description

export facotry default stored searches to an XML file

Parameters

oiReturnStatus

output

integer

Return status of the method.

Internal usage

unused

program code (program3/bstoredsearch.p)

if oiReturnStatus = 0
then oiReturnStatus = -98.

/* ===================================== */
/* Determine filename of export-xml-file */
/* ===================================== */
<M-64 run Main  (input  viSessionID (iiSessionId)) in TApplication>
<M-73 run GetDefaultsFolder  (output vcFilePath (ocFolder)) in TApplication>
run gipr_DeleteProcedure in vhFcComponent.
delete procedure vhFcComponent.

assign vcFileName = "factorydefaults.xml":U
       vcFile     = trim(vcFilePath) + trim(vcFileName).

/* ================================================= */
/* Load the factory default stored searches          */
/* ================================================= */
assign vcFreeform = "for each StoredSearch where StoredSearch.Usr_ID = 0 and StoredSearch.Role_ID = 0 and StoredSearch.StoredSearchName = '":U + {&STOREDSEARCH-FACTORY-DEFAULT} + "'":U.
<M-9 run DataLoad (input  '' (icRowids), 
                   input  '' (icPkeys), 
                   input  '' (icObjectIds), 
                   input  vcFreeform (icFreeform), 
                   input  no (ilKeepPrevious), 
                   output viFcReturnSuper (oiReturnStatus)) in BStoredSearch>
if viFcReturnSuper <> 0
then oiReturnStatus = viFcReturnSuper.
if viFcReturnSuper < 0
then return.

/* ================================================================= */
/* Standardise the data before dumping, so it becomes easier to      */
/* compare different versions of the output file.                    */
/* - Clear contents of LastModifiedDate-Time-User.                   */
/* - Assign fixed values to tc_Rowid and tc_ParentRowid.             */
/* - Sort stored searches on lookup reference.                       */
/* ================================================================= */
for each tStoredSearch by tStoredSearch.StoredSearchLookupRef on error undo, throw:

    for each tSSearchFilterField where tSSearchFilterField.tc_ParentRowid = tStoredSearch.tc_Rowid
             break by tSSearchFilterField.SSearchFilterFieldBusField 
                   by tSSearchFilterField.SSearchFilterFieldSequence
                   by tSSearchFilterField.SSearchFilterFieldOperator
                   by tSSearchFilterField.SSearchFilterFieldIniVal1
                   by tSSearchFilterField.SSearchFilterFieldIsVisibl
                   on error undo, throw:

        if first-of (tSSearchFilterField.SSearchFilterFieldBusField)
        then viSSearchFilterFieldRowid = 0.

        assign viSSearchFilterFieldRowid            = viSSearchFilterFieldRowid + 1
               tSSearchFilterField.LastModifiedDate = ?
               tSSearchFilterField.LastModifiedTime = 0
               tSSearchFilterField.LastModifiedUser = ""
               tSSearchFilterField.tc_ParentRowid   = tStoredSearch.StoredSearchLookupRef
               tSSearchFilterField.tc_Rowid         = tStoredSearch.StoredSearchLookupRef
                                                    + "." + tSSearchFilterField.SSearchFilterFieldBusField
                                                    + (if viSSearchFilterFieldRowid = 1
                                                       then ""
                                                       else "." + string(viSSearchFilterFieldRowid)).
    end.

    for each tSSearchResultField where tSSearchResultField.tc_ParentRowid = tStoredSearch.tc_Rowid
             break by tSSearchResultField.SSearchResultFieldBusField 
                   by tSSearchResultField.SSearchResultFieldSequence
             on error undo, throw:

        if first-of (tSSearchResultField.SSearchResultFieldBusField)
        then viSSearchResultFieldRowid = 0.

        assign viSSearchResultFieldRowid            = viSSearchResultFieldRowid + 1
               tSSearchResultField.LastModifiedDate = ?
               tSSearchResultField.LastModifiedTime = 0
               tSSearchResultField.LastModifiedUser = ""
               tSSearchResultField.tc_ParentRowid   = tStoredSearch.StoredSearchLookupRef
               tSSearchResultField.tc_Rowid         = tStoredSearch.StoredSearchLookupRef
                                                    + "." + tSSearchResultField.SSearchResultFieldBusField
                                                    + (if viSSearchResultFieldRowid = 1
                                                       then ""
                                                       else "." + string(viSSearchResultFieldRowid)).
    end.
    
    assign tStoredSearch.LastModifiedDate = ?
           tStoredSearch.LastModifiedTime = 0
           tStoredSearch.LastModifiedUser = ""
           tStoredSearch.tc_Rowid         = tStoredSearch.StoredSearchLookupRef.
end.

/* ================================================================= */
/* Remove any custom field settings                                  */
/* ================================================================= */
for each tSSearchFilterField where num-entries(tSSearchFilterField.SSearchFilterFieldBusField,".") = 2:
    vcField = entry(2,tSSearchFilterField.SSearchFilterFieldBusField,".").
    if vcField begins "CustomShort"
    or vcField begins "CustomCombo"
    or vcField begins "CustomLong"
    or vcField begins "CustomNote"
    or vcField begins "CustomDate"
    or vcField begins "CustomInteger"
    or vcField begins "CustomDecimal"
    then delete tSSearchFilterField.
end.

for each tSSearchResultField where num-entries(tSSearchResultField.SSearchResultFieldBusField,".") = 2:
    vcField = entry(2,tSSearchResultField.SSearchResultFieldBusField,".").
    if num-entries(vcField,"_") = 2
    then
    if entry(2,vcField,"_") begins "CustomShort"
    or entry(2,vcField,"_") begins "CustomCombo"
    or entry(2,vcField,"_") begins "CustomLong"
    or entry(2,vcField,"_") begins "CustomNote"
    or entry(2,vcField,"_") begins "CustomDate"
    or entry(2,vcField,"_") begins "CustomInteger"
    or entry(2,vcField,"_") begins "CustomDecimal"
    then delete tSSearchResultField.
end.

/* ============================================= */
/* Dump the data in the instance to the XML-file */
/* ============================================= */
<M-4 run DumpXmlRepresentation
   (input  vcFile (icFile), 
    input  false (ilHeaderOnly), 
    input  ? (ilSuppressEmptyFields), 
    input  0 (iiPriority), 
    input  false (ilWriteXMLSchema), 
    input  ? (icObjectRowId), 
    input  true (ilExportForInput), 
    output viFcReturnSuper (oiReturnStatus)) in BStoredSearch>
    
if viFcReturnSuper <> 0
then oiReturnStatus = viFcReturnSuper.
if viFcReturnSuper < 0
then return.

/* ================================================================================ */
/* Clear the data in the Component again, to make sure the changes are not commited */
/* ================================================================================ */
<M-8 run ClearData (output viFcReturnSuper (oiReturnStatus)) in BStoredSearch>
if viFcReturnSuper <> 0
then oiReturnStatus = viFcReturnSuper.
if viFcReturnSuper < 0
then return.

if oiReturnStatus = -98
then oiReturnStatus = 0.

Sample code: how to call this method through RPCRequestService (QXtend Inbound)

define temp-table ttContext no-undo
    field propertyQualifier as character
    field propertyName as character
    field propertyValue as character
    index entityContext is primary unique
        propertyQualifier
        propertyName
    index propertyQualifier
        propertyQualifier.

define dataset dsContext for ttContext.

define variable vhContextDS as handle no-undo.
define variable vhExceptionDS as handle no-undo.
define variable vhServer as handle no-undo.
define variable vhInputDS as handle no-undo.
define variable vhInputOutputDS as handle no-undo.
define variable vhOutputDS as handle no-undo.
define variable vhParameter as handle no-undo.

/* Create context */
create ttContext.
assign ttContext.propertyName = "programName"
       ttContext.propertyValue = "BStoredSearch".
create ttContext.
assign ttContext.propertyName = "methodName"
       ttContext.propertyValue = "apiExportFactoryDefaults".
create ttContext.
assign ttContext.propertyName = "applicationId"
       ttContext.propertyValue = "fin".
create ttContext.
assign ttContext.propertyName = "entity"
       ttContext.propertyValue = "1000".
create ttContext.
assign ttContext.propertyName = "userName"
       ttContext.propertyValue = "mfg".
create ttContext.
assign ttContext.propertyName = "password"
       ttContext.propertyValue = "".

/* Connect the AppServer */
create server vhServer.
vhServer:connect("-URL <appserver-url>").

if not vhServer:connected()
then do:
    message "Could not connect AppServer" view-as alert-box error title "Error".
    return.
end.

/* Run */
assign vhContextDS = dataset dsContext:handle.

run program/rpcrequestservice.p on vhServer
    (input-output dataset-handle vhContextDS by-reference,
           output dataset-handle vhExceptionDS,
     input        dataset-handle vhInputDS by-reference,
     input-output dataset-handle vhInputOutputDS by-reference,
           output dataset-handle vhOutputDS).

/* Handle output however you want, in this example, we dump it to xml */
if valid-handle(vhExceptionDS)
then vhExceptionDS:write-xml("file", "Exceptions.xml", true).

if valid-handle(vhOutputDS)
then vhOutputDS:write-xml("file", "Output.xml", true).

/* Cleanup */
vhServer:disconnect().
assign vhServer = ?.

if valid-handle(vhInputDS)
then delete object vhInputDS.

if valid-handle(vhOutputDS)
then delete object vhOutputDS.

if valid-handle(vhExceptionDS)
then delete object vhExceptionDS.